aboutsummaryrefslogtreecommitdiff
path: root/tests/manifest-serializer/testscript
blob: 952f99462aa92b15dc14007700248fff6266d6ee (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
# file      : tests/manifest-serializer/testscript
# license   : MIT; see accompanying LICENSE file

: stdout
:
{
  $* <<EOI >>EOO

    1

    name
    foo

    version
    1.2.3

    description
    foo
    executable

    depends
    libfoo

    depends
    libbar

    EOI
    : 1
    name: foo
    version: 1.2.3
    description: \
    foo
    executable
    \
    depends: libfoo
    depends: libbar
    EOO
}

: file
:
{
  $* <<EOI >=file;

    1

    name
    foo

    version
    1.2.3
    EOI

  cat file >>EOE
    : 1
    name: foo
    version: 1.2.3
    EOE
}

: list
:
{
  $* <<EOI >>EOO

    1

    name
    foo


    1

    version
    1.2.3
    EOI
    : 1
    name: foo
    :
    version: 1.2.3
    EOO
}

: break-lines
:
{
  $* <<EOI >>EOO

    1

    name
    foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
    EOI
    : 1
    name: foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo\
    oooo
    EOO
}

: long-lines
:
{
  : file
  :
  {
    $* --long-lines file <<EOI >=file;

      1

      name
      foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
      EOI

    cat file >>EOO
      : 1
      name: foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
      EOO
  }

  : stdout
  :
  {
    $* --long-lines <<EOI >>EOO

      1

      name
      foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
      EOI
      : 1
      name: foooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
      EOO
  }
}

: version
:
{
  : absent
  :
  $* <<EOI 2>'stdout: error: format version pair expected' != 0
    name
    foo
    EOI
}

: empty
:
{
  $* <:'' >:''
}