aboutsummaryrefslogtreecommitdiff
path: root/tests/manifest/task.testscript
blob: 8320f598bf4f2a2527a9713538ad014ad6d29b8b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
# file      : tests/manifest/task.testscript
# license   : MIT; see accompanying LICENSE file

test.options += -t

: valid
:
: Roundtrip the task manifest.
:
{
  : all-names
  :
  $* <<EOF >>EOF
  : 1
  name: foo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  trust: AB:0D:3F:C1:B0:13:E4:0E:AD:4A:08:06:AE:F3:85:DB:E2:27:5F:83:11:47:A2:7\
  8:64:3C:73:60:F8:66:3A:A4
  requires: host
  tests: foo-tests
  examples: foo-examples
  dependency-checksum: 12345
  machine: windows_10-msvc_14
  auxiliary-machine-pgsql: x86_64-linux_debian_12-postgresql_16
  auxiliary-machine: x86_64-linux_debian_12-mysql*
  target: x86_64-microsoft-win32-msvc14.0
  environment: lld
  auxiliary-environment:\
  PGSQL_DATABASE_HOST=192.168.0.1
  PGSQL_DATABASE_PORT=1245
  \
  target-config: config.cc.coptions=/Z7 config.cc.loptions=/DEBUG
  package-config: config.foo.network=true
  warning-regex: '^warning: ' '^.+: warning: '
  interactive: error
  worker-checksum: 1
  EOF

  # @@ TMP Remove when toolchain 0.16.0 is released.
  #
  : no-package-config
  :
  $* <<EOF >>EOF
  : 1
  name: foo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  trust: AB:0D:3F:C1:B0:13:E4:0E:AD:4A:08:06:AE:F3:85:DB:E2:27:5F:83:11:47:A2:7\
  8:64:3C:73:60:F8:66:3A:A4
  requires: host
  tests: foo-tests
  examples: foo-examples
  dependency-checksum: 12345
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  environment: lld
  config: config.cc.coptions=/Z7 config.cc.loptions=/DEBUG
  warning-regex: '^warning: ' '^.+: warning: '
  interactive: error
  worker-checksum: 1
  EOF

  : no-config-regex-environment
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  EOF

  : typed-url
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  repository-url: git+http://example.org/math
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  EOF

  : repo-type
  :
  $* <<EOI >>EOO
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://git.example.org/math
  repository-type: git
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  EOI
  : 1
  name: libfoo
  version: 1.0
  repository-url: git+http://git.example.org/math
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  EOO

  : requires
  :
  {
    $* <<EOF >>EOF
    : 1
    name: foo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    requires: {c++ >= 14 windows}
    requires: host
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    EOF
  }

  : requires-invalid
  :
  {
    $* <<EOI 2>>EOE != 0
    : 1
    name: foo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    requires: {c++ >= 14 windows
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    EOI
    stdin:5:29: error: requirement or '}' expected
    EOE
  }

  : tests
  :
  {
    $* <<EOF >>EOF
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    tests: libfoo-tests
    examples: libfoo-examples == 1.2.3
    benchmarks: libfoo-benchmarks ~1.2.0
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    EOF
  }

  : config
  :
  {
    : empty-var-value
    :
    $* <<EOF >>EOF
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    config: abc=
    EOF

    : var-value-quoting
    :
    $* <<EOF >>EOF
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    config: abc='a "b '"d\e x y="
    EOF
  }

  : host
  :
  {
    : true
    :
    $* <<EOF >>EOF
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    host: true
    EOF

    : false
    :
    $* <<EOF >>EOF
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows
    target: x86_64-microsoft-win32-msvc14.0
    host: false
    EOF
  }

  : trust-yes
  :
  $* <<EOF >>EOF
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  trust: yes
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  config: config.cc.coptions=/Z7 config.cc.loptions=/DEBUG
  EOF
}

: redefinition
:
{
  : name
  :
  $* <<EOI 2>'stdin:3:1: error: task package name redefinition' == 1
  : 1
  name: libfoo
  name: libfoo
  EOI

  : version
  :
  $* <<EOI 2>'stdin:3:1: error: task package version redefinition' == 1
  : 1
  version: 1.0
  version: 1.0
  EOI

  : repository
  :
  $* <<EOI 2>'stdin:3:1: error: task repository URL redefinition' == 1
  : 1
  repository-url: http://pkg.example.org/1/math
  repository-url: http://pkg.example.org/1/math
  EOI

  : machine
  :
  $* <<EOI 2>'stdin:3:1: error: task machine redefinition' == 1
  : 1
  machine: windows_10-msvc_14
  machine: windows_10-msvc_14
  EOI

  : auxiliary-machine
  :
  $* <<EOI 2>'stdin:3:1: error: task auxiliary machine environment redefinition' == 1
  : 1
  auxiliary-machine-pgsql: x86_64-linux_debian_12-postgresql_16
  auxiliary-machine-pgsql: x86_64-linux_debian_12-postgresql_14
  EOI

  : target
  :
  $* <<EOI 2>'stdin:3:1: error: task target redefinition' == 1
  : 1
  target: x86_64-microsoft-win32-msvc14.0
  target: x86_64-microsoft-win32-msvc14.0
  EOI

  : auxiliary-environment
  :
  $* <<EOI 2>'stdin:7:1: error: task auxiliary environment redefinition' == 1
  : 1
  auxiliary-environment:
  \
  PGSQL_DATABASE_HOST=192.168.0.1
  PGSQL_DATABASE_PORT=1245
  \
  auxiliary-environment:
  \
  PGSQL_DATABASE_HOST=192.168.0.1
  PGSQL_DATABASE_PORT=1245
  \
  EOI

  : config
  :
  $* <<EOI 2>'stdin:3:1: error: task target configuration redefinition' == 1
  : 1
  config: config.cc.coptions=/Z7
  config: config.cc.loptions=/DEBUG
  EOI

  : host
  :
  $* <<EOI 2>'stdin:3:1: error: task host value redefinition' == 1
  : 1
  host: true
  host: false
  EOI

  : warning-regex
  :
  $* <<EOI 2>'stdin:3:1: error: task warning regex redefinition' == 1
  : 1
  warning-regex: '^warning: '
  warning-regex: '^.+: warning: '
  EOI

  : interactive
  :
  $* <<EOI 2>'stdin:3:1: error: task interactive value redefinition' == 1
  : 1
  interactive: error
  interactive: warning
  EOI

  : worker-checksum
  :
  $* <<EOI 2>'stdin:3:1: error: task worker checksum redefinition' == 1
  : 1
  worker-checksum: 1
  worker-checksum: 1
  EOI
}

: invalid
:
{
  : name-empty
  :
  $* <<EOI 2>'stdin:2:6: error: invalid task package name: length is less than two characters' == 1
  : 1
  name:
  EOI

  : version
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:9: error: invalid task package version: unexpected end' == 1
    : 1
    version:
    EOI

    : release
    :
    $* <<EOI 2>'stdin:2:10: error: invalid task package version release' == 1
    : 1
    version: 1.2.3-
    EOI
  }

  : repository
  :
  {
    : url
    :
    $* <<EOI 2>>EOE == 1
    : 1
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/math
    repository-type: pkg
    machine: windows_10-msvc_14
    target: x86_64-microsoft-win32-msvc14.0
    EOI
    stdin:4:17: error: invalid task repository URL: missing repository version
    EOE

    : type
    :
    $* <<EOI 2>>EOE == 1
    : 1
    repository-type: svn
    EOI
    stdin:2:18: error: invalid task repository type 'svn'
    EOE
  }

  : machine-empty
  :
  $* <<EOI 2>'stdin:2:9: error: empty task machine' == 1
  : 1
  machine:
  EOI

  : target-empty
  :
  $* <<EOI 2>'stdin:2:8: error: invalid task target: missing cpu' == 1
  : 1
  target:
  EOI

  : target-config
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:8: error: empty task target configuration' == 1
    : 1
    config:
    EOI

    : bad-field
    :
    $* <<EOI 2>'stdin:2:15: error: invalid task configuration: unterminated quoted string' == 1
    : 1
    config: 'abc=x
    EOI

    : multiline
    :
    {
      : bad-field
      :
      $* <<EOI 2>'stdin:3:7: error: invalid task configuration: unterminated quoted string' == 1
      : 1
      config:\
      'abc=x
      \
      EOI
    }
  }

  : host
  :
  $* <<EOI 2>"stdin:2:7: error: invalid task host value 'yes'" == 1
  : 1
  host: yes
  EOI

  : warning-regex
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:15: error: empty task warning regex' == 1
    : 1
    warning-regex:
    EOI

    : regex-error
    :
    $* <<EOI 2>>~/EOE/ == 1
    : 1
    warning-regex: '^[warning: '
    EOI
    /stdin:2:16: error: invalid task warning regex: invalid regex.*/
    EOE
  }

  : trust
  :
  $* <<EOI 2>'stdin:2:8: error: invalid repository certificate fingerprint' == 1
  : 1
  trust: abc
  EOI

  : interactive
  :
  $* <<EOI 2>'stdin:2:13: error: empty task interactive value' == 1
  : 1
  interactive:
  EOI

  : worker-checksum
  :
  $* <<EOI 2>'stdin:2:17: error: empty task worker checksum' == 1
  : 1
  worker-checksum:
  EOI
}

: unknown-name
:
$* <<EOI 2>"stdin:2:1: error: unknown name 'x' in task manifest" == 1
: 1
x:
EOI

: missed
:
{
  : name
  :
  $* <<EOI 2>'stdin:6:1: error: no task package name specified' == 1
  : 1
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  repository-type: pkg
  machine: windows_10-msvc_14
  EOI

  : version
  :
  $* <<EOI 2>'stdin:6:1: error: no task package version specified' == 1
  : 1
  name: libfoo
  repository-url: http://pkg.example.org/1/math
  repository-type: pkg
  machine: windows_10-msvc_14
  EOI

  : repository-url
  :
  $* <<EOI 2>'stdin:6:1: error: no task repository URL specified' == 1
  : 1
  name: libfoo
  version: 1.0
  machine: windows_10-msvc_14
  repository-type: git
  EOI

  : repository-type
  :
  $* <<EOI 2>'stdin:4:17: error: invalid task repository URL: missing repository version' == 1
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://git.example.org/math
  machine: windows_10-msvc_14
  target: x86_64-microsoft-win32-msvc14.0
  EOI

  : machine
  :
  $* <<EOI 2>'stdin:6:1: error: no task machine specified' == 1
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  repository-type: pkg
  EOI

  : target
  :
  $* <<EOI 2>'stdin:7:1: error: no task target specified' == 1
  : 1
  name: libfoo
  version: 1.0
  repository-url: http://pkg.example.org/1/math
  repository-type: pkg
  machine: windows_10-msvc_14
  EOI
}