aboutsummaryrefslogtreecommitdiff
path: root/tests/rep-info.testscript
blob: 55a29da0a419a5a8a20e4da4240a8a708f2ae7dc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
# file      : tests/rep-info.testscript
# copyright : Copyright (c) 2014-2018 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

.include common.testscript \
	 auth.testscript \
	 remote.testscript \
	 remote-git.testscript

# Source repository:
#
# rep-info
# |-- testing             -> stable (complement), ../foo/testing (prerequisite)
# |   |-- foo-1.tar.gz
# |   `-- repositories.manifest
# |
# `-- git
#     |-- libbar.git      -> style-basic.git (prerequisite)
#     `-- style-basic.git

# Prepare repositories used by tests if running in the local mode.
#
+if ($remote != true)
  rc = $rep_create 2>!

  # Create the unsigned 'testing' repository.
  #
  cp -r $src/testing $out/testing
  $rc $out/testing &$out/testing/packages.manifest

  # Create the signed 'testing' repository.
  #
  cp -r $src/testing $out/signed
  cat <<<$cert_manifest >+$out/signed/repositories.manifest

  $rc --key $key $out/signed &$out/signed/packages.manifest \
                             &$out/signed/signature.manifest

  # Create git repositories.
  #
  $git_extract $src/git/libbar.tar
  $git_extract $src/git/style-basic.tar &$out_git/state0/***
end

test.options += --auth all --trust-yes

: no-location
:
$* 2>>EOE != 0
error: repository location argument expected
  info: run 'bpkg help rep-info' for more information
EOE

: default
:
{
  : unsigned
  :
  $* $rep/testing >>"EOO"
  pkg:build2.org/rep-info/testing ($rep/testing)
  prerequisite pkg:build2.org/foo/testing ($rep_root/foo/testing)
  complement pkg:build2.org/rep-info/stable ($rep/stable)

  foo/1
  EOO

  : signed
  :
  $* $rep/signed >>"EOO"
  pkg:build2.org/rep-info/signed ($rep/signed)
  CN=build2.org/O=Code Synthesis/info@build2.org
  $cert_fp
  prerequisite pkg:build2.org/foo/testing ($rep_root/foo/testing)
  complement pkg:build2.org/rep-info/stable ($rep/stable)

  foo/1
  EOO
}

: name
:
$* --name $rep/testing >"pkg:build2.org/rep-info/testing ($rep/testing)"

: packages
:
{
  test.arguments += --packages # Should go after the rep-info command argument.

  : list
  :
  $* $rep/testing >>EOO

  foo/1
  EOO

  : manifest
  :
  $* --manifest $rep/testing >>EOO
  : 1
  name: foo
  version: 1
  summary: The "Foo" utility
  license: MIT
  url: http://www.example.org/foo
  email: foo-users@example.org
  location: foo-1.tar.gz
  sha256sum: fee330a362a4f87ff42a954aa305b6446d541b7b60000ebcd2fbf68f2b1ae58e
  EOO

  : to-file
  :
  {
    : no-manifest
    :
    $* --packages-file m $rep/testing 2>>EOE != 0
    error: --packages-file specified without --manifest
      info: run 'bpkg help rep-info' for more information
    EOE

    : manifest
    :
    {
      $* --manifest --packages-file m $rep/testing &m;

      cat m >>EOO
        : 1
        name: foo
        version: 1
        summary: The "Foo" utility
        license: MIT
        url: http://www.example.org/foo
        email: foo-users@example.org
        location: foo-1.tar.gz
        sha256sum: fee330a362a4f87ff42a954aa305b6446d541b7b60000ebcd2fbf68f2b1ae58e
        EOO
    }
  }
}

: repositories
:
{
  # Should go after the rep-info command argument.
  #
  test.arguments += --repositories

  : list
  :
  $* $rep/testing >>"EOO"
  prerequisite pkg:build2.org/foo/testing ($rep_root/foo/testing)
  complement pkg:build2.org/rep-info/stable ($rep/stable)
  EOO

  : manifest
  :
  $* --manifest $rep/testing >>EOO
  : 1
  location: ../../foo/testing
  type: pkg
  role: prerequisite
  :
  location: ../stable
  type: pkg
  role: complement
  :
  EOO

  : to-file
  :
  {
    : no-manifest
    :
    $* --repositories-file m $rep/testing 2>>EOE != 0
    error: --repositories-file specified without --manifest
      info: run 'bpkg help rep-info' for more information
    EOE

    : manifest
    :
    {
      $* --manifest --repositories-file m $rep/testing &m;

      cat m >>EOO
        : 1
        location: ../../foo/testing
        type: pkg
        role: prerequisite
        :
        location: ../stable
        type: pkg
        role: complement
        :
        EOO
    }
  }
}

: cert
:
{
  test.arguments += $rep/signed

  $* --cert-fingerprint  >"$cert_fp"        : fingerprint
  $* --cert-name         >'name:build2.org' : name
  $* --cert-organization >'Code Synthesis'  : organization
  $* --cert-email        >'info@build2.org' : email
}

: git-rep
:
if ($git_supported != true)
{
  # Skip git repository tests.
  #
}
else
{
  rep = "$rep_git/state0"
  test.redirects += 2>!

  : version-module
  :
  : Version module is enabled for the project.
  :
  $* "$rep/style-basic.git#master" >>~%EOO%
  %git:.+style-basic#master .+style-basic.git#master%

  %style-basic/1\.1\.0-a\.0\.\d+\..+%
  EOO

  : manifest-lists
  :
  : The packages.manifest and repositories.manifest files are present in the
  : repository root.
  :
  $* "$rep/libbar.git#master" >>~%EOO%
  %git:.+libbar#master .+libbar.git#master%
  %prerequisite git:.+style-basic#stable .+style-basic.git#stable%

  libbar/1.0.0
  libmbar/1.0.0
  EOO

  : repository-manifests
  :
  : Here we test that the base repository manifest that comes from the stable
  : branch is printed because the stable head commit is newer that of the
  : master branch.
  :
  $* -r --manifest "$rep/style-basic.git#stable,master" >>~%EOO%
  : 1
  email: user@example.com
  EOO

  : complete-dependency
  :
  $* -p --manifest "$rep/libbar.git#master" >>~%EOO%d
    : 1
    name: libbar
    version: 1.0.0
    summary: libbar
    license: MIT
    url: http://example.org/libbar
    email: pkg@example.org
    depends: style-basic >= 1.0.0
    location: libbar
    %fragment: \.+%
    :
    name: libmbar
    version: 1.0.0
    summary: libmbar
    license: MIT
    url: http://example.org/libmbar
    email: pkg@example.org
    depends: style-basic >= 1.0.0
    location: libmbar
    %fragment: \.+%
    EOO
}