tests/cfg-create.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291

# file      : tests/cfg-create.testscript
# license   : MIT; see accompanying LICENSE file

.include common.testscript

config_cxx = [cmdline] config.cxx=$quote($recall($cxx.path) $cxx.config.mode, true)

cfg_create += 2>!

cfg_info   += -d cfg
pkg_status += -d cfg

: non-empty
:
$* 2>>/~%EOE% != 0
error: directory ./ is not empty
  info: use --wipe to clean it up but be careful
EOE

: dir
:
{
  test.arguments += -d cfg
  test.cleanups  += &cfg/***

  : no-vars-mods
  :
  {
    $* 2>>/~%EOE%;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : conf-var
  :
  {
    $* "config.install.root='$~/opt'" 2>>/~%EOE%;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown';

    cat cfg/build/config.build >>/~"%EOO%"
      %.+
      %config.install.root = '?.+/opt/'?%
      %.+
      EOO
  }

  : module
  :
  {
    $* cxx $config_cxx 2>>/~%EOE%;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown';

    cat cfg/build/config.build >>/~"%EOO%"
      %.+
      %config.cxx = .+%
      %.+
      EOO
  }

  : wipe
  :
  {
    mkdir -p cfg/foo/bar &!cfg/ &!cfg/foo/ &!cfg/foo/bar/;

    $* --wipe 2>>/~%EOE%;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : existing
  :
  {
    $build 'create(cfg/,cc)' $config_cxx 2>!;

    $* --existing 2>>/~%EOE%;
      %initialized existing configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }
}

: name
:
{
  test.arguments += -d cfg

  : valid
  :
  {
    $* --name foo 2>>/~%EOE% &cfg/***;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
        name: foo
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      name: foo
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : invalid
  :
  : Also use the short option.
  :
  $* --name 123 2>>EOE != 0
    error: invalid --name option value '123': illegal first character (must be alphabetic or underscore)
    EOE
}

: type
:
{
  test.arguments += -d cfg

  : valid
  :
  {
    $* --type host 2>>/~%EOE% &cfg/***;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: host
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: host
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : invalid
  :
  : Also use the short option.
  :
  $* --type '' 2>>EOE != 0
    error: empty --type option value
    EOE
}

: uuid
:
{
  test.arguments += -d cfg

  : valid
  :
  {
    uuid='18f48b4b-b5d9-4712-b98c-1930df1c4228';

    $* --uuid $uuid --name foo 2>>/~"%EOE%" &cfg/***;
      %created new configuration in .+/cfg/%
        uuid: $uuid
        type: target
        name: foo
      EOE

    $cfg_info >>/~"%EOO%";
      %path: .+/cfg/%
      uuid: $uuid
      type: target
      name: foo
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : invalid
  :
  : Also use the short option.
  :
  $* --uuid '123' 2>>EOE != 0
    error: invalid value '123' for option '--uuid'
    EOE
}

: link-config
:
{
  test.arguments += -d cfg

  : valid-type
  :
  {
    $cfg_create -d host   --type 'host'   &host/***;
    $cfg_create -d build2 --type 'build2' &build2/***;

    $* --host-config host --build2-config build2 2>>/~%EOE% &cfg/***;
      %created new configuration in .+/cfg/%
      %  uuid: .{36}%
        type: target
      EOE

    $cfg_info --link >>/~"%EOO%";
      %path: .+/cfg/%
      %uuid: .{36}%
      type: target
      %name: %

      %path: .+/host/%
      %uuid: .{36}%
      type: host
      %name: %

      %path: .+/build2/%
      %uuid: .{36}%
      type: build2
      %name: %
      EOO

    $pkg_status libfoo >'libfoo unknown'
  }

  : invalid-type
  :
  {
    $cfg_create -d cfg2 &cfg2/***;

    $* --host-config cfg2 2>>/~%EOE% != 0;
      %error: host configuration .+/cfg2/ is of 'target' type%
      EOE

    $* --build2-config cfg2 2>>/~%EOE% != 0
      %error: build2 configuration .+/cfg2/ is of 'target' type%
      EOE
  }
}