bpkg/system-package-manager.test.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158

# file      : bpkg/system-package-manager.test.testscript
# license   : MIT; see accompanying LICENSE file

: system-package-names
:
{
  test.arguments += system-package-names

  : basics
  :
  cat <<EOI >=libcurl7.64.manifest;
    : 1
    name: libcurl
    version: 7.64.0
    debian-name: libcurl2 libcurl2-dev
    summary: curl
    license: curl
    EOI
  cat <<EOI >=libcurl7.84.manifest;
    : 1
    name: libcurl
    version: 7.84.0
    debian_9-name: libcurl2 libcurl2-dev libcurl2-doc
    debian_10-name: libcurl4 libcurl4-openssl-dev
    debian_10-name: libcurl3-gnutls libcurl4-gnutls-dev
    summary: curl
    license: curl
    EOI

  $* debian 10 -- libcurl libcurl7.64.manifest libcurl7.84.manifest >>EOO;
    libcurl4 libcurl4-openssl-dev
    libcurl3-gnutls libcurl4-gnutls-dev
    libcurl2 libcurl2-dev libcurl2-doc
    libcurl2 libcurl2-dev
    EOO
  $* debian 9 -- libcurl libcurl7.64.manifest libcurl7.84.manifest >>EOO;
    libcurl2 libcurl2-dev libcurl2-doc
    libcurl2 libcurl2-dev
    EOO
  $* debian '' -- libcurl libcurl7.64.manifest libcurl7.84.manifest >>EOO;
    libcurl2 libcurl2-dev
    EOO
  $* ubuntu 16.04 debian -- libcurl libcurl7.64.manifest libcurl7.84.manifest >>EOO
    libcurl2 libcurl2-dev
    EOO

  : native
  :
  cat <<EOI >=libcurl.manifest;
    : 1
    name: libcurl
    version: 7.84.0
    debian-name: libcurl4 libcurl4-openssl-dev
    debian_0-name: libcurl libcurl-dev
    summary: curl
    license: curl
    EOI
  $* debian 10 -- libcurl libcurl.manifest >>EOO;
    libcurl4 libcurl4-openssl-dev
    EOO
  $* debian 10 -- --non-native libcurl libcurl.manifest >>EOO
    libcurl libcurl-dev
    EOO
}

: system-package-version
:
{
  test.arguments += system-package-version

  : basics
  :
  cat <<EOI >=libssl1.1.1+19.manifest;
    : 1
    name: libssl
    version: 1.1.1+19
    fedora-name: openssl-libs
    fedora-version: 1:1.1.1q-1
    fedora_35-version: 1:1.1.1q-1.fc35
    fedora_36-version: 1:1.1.1q-1.fc36
    summary: openssl
    license: openssl
    EOI

  $* fedora 34 -- libssl libssl1.1.1+19.manifest >>EOO;
    1:1.1.1q-1
    EOO
  $* fedora 35 -- libssl libssl1.1.1+19.manifest >>EOO;
    1:1.1.1q-1.fc35
    EOO
  $* fedora 36 -- libssl libssl1.1.1+19.manifest >>EOO;
    1:1.1.1q-1.fc36
    EOO
  $* fedora 37 -- libssl libssl1.1.1+19.manifest >>EOO;
    1:1.1.1q-1.fc36
    EOO
  $* fedora '' -- libssl libssl1.1.1+19.manifest >>EOO;
    1:1.1.1q-1
    EOO
  $* rhel 7.8 fedora -- libssl libssl1.1.1+19.manifest >>EOO
    1:1.1.1q-1
    EOO
}

: downstream-package-version
:
{
  test.arguments += downstream-package-version

  : basics
  :
  cat <<EOI >=libssl1.manifest;
    : 1
    name: libssl
    version: 1.1.1
    upstream-version: 1.1.1n
    debian-to-downstream-version: /1\.1\.1[a-z]/1.1.1/
    summary: openssl
    license: openssl
    EOI
  cat <<EOI >=libssl3.manifest;
    : 1
    name: libssl
    version: 3.0.0
    debian-to-downstream-version: /([3-9])\.([0-9]+)\.([0-9]+)/\1.\2.\3/
    summary: openssl
    license: openssl
    EOI
  $* debian 10 -- 1.1.1l libssl libssl1.manifest libssl3.manifest >'1.1.1';
  $* debian 10 -- 3.0.7  libssl libssl1.manifest libssl3.manifest >'3.0.7';
  $* debian '' -- 1.1.1l libssl libssl1.manifest libssl3.manifest >'1.1.1';
  $* debian '' -- 3.0.7  libssl libssl1.manifest libssl3.manifest >'3.0.7';
  $* ubuntu 16.04 debian -- 1.1.1l libssl libssl1.manifest libssl3.manifest >'1.1.1';
  $* ubuntu 16.05 debian -- 3.0.7  libssl libssl1.manifest libssl3.manifest >'3.0.7'

  : order
  :
  cat <<EOI >=libssl1.manifest;
    : 1
    name: libssl
    version: 1.1.1
    debian-to-downstream-version: /.*/0/
    summary: openssl
    license: openssl
    EOI
  cat <<EOI >=libssl3.manifest;
    : 1
    name: libssl
    version: 3.0.0
    debian_9-to-downstream-version: /.*/9/
    debian_10-to-downstream-version: /.*/10/
    summary: openssl
    license: openssl
    EOI
  $* debian 10 -- 1 libssl libssl1.manifest libssl3.manifest >'10';
  $* debian  9 -- 1 libssl libssl1.manifest libssl3.manifest >'9';
  $* debian  8 -- 1 libssl libssl1.manifest libssl3.manifest >'0'
}