tests/manifest/task-response.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190

# file      : tests/manifest/task-response.testscript
# license   : MIT; see accompanying LICENSE file

test.options += -ts

: valid
:
: Roundtrip the task response manifest.
:
{
  : session-not-empty
  :
  {
    : all-values
    :
    $* <<EOF >>EOF
    : 1
    session: abcd
    challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
    result-url: https://cppget.org/?build-result
    agent-checksum: 1
    :
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows_10-msvc_14
    target: x86_64-microsoft-win32-msvc14.0
    EOF

    : no-optional
    :
    $* <<EOF >>EOF
    : 1
    session: abcd
    result-url: https://cppget.org/?build-result
    :
    name: libfoo
    version: 1.0
    repository-url: http://pkg.example.org/1/math
    machine: windows_10-msvc_14
    target: x86_64-microsoft-win32-msvc14.0
    EOF
  }

  : session-empty
  :
  $* <<EOF >>EOF
  : 1
  session:
  EOF
}

: redefinition
:
{
  : session
  :
  $* <<EOI 2>'stdin:3:1: error: task response session redefinition' == 1
  : 1
  session: abcd
  session: abcd
  EOI

  : challenge
  :
  $* <<EOI 2>'stdin:3:1: error: task response challenge redefinition' == 1
  : 1
  challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
  challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
  EOI

  : result-url
  :
  $* <<EOI 2>'stdin:3:1: error: task response result url redefinition' == 1
  : 1
  result-url: https://cppget.org/?build-result
  result-url: https://cppget.org/?build-result
  EOI

  : agent-checksum
  :
  $* <<EOI 2>'stdin:3:1: error: task response agent checksum redefinition' == 1
  : 1
  agent-checksum: 1
  agent-checksum: 1
  EOI
}

: invalid
:
{
  : challenge
  :
  {
    : size
    :
    $* <<EOI 2>'stdin:2:12: error: invalid task response challenge' == 1
    : 1
    challenge: abc
    EOI

    : redundant
    :
    $* <<EOI 2>'stdin:4:1: error: unexpected task response challenge' == 1
    : 1
    session:
    challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
    EOI
  }

  : result-url
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:12: error: empty task response result url' == 1
    : 1
    result-url:
    EOI

    : redundant
    :
    $* <<EOI 2>'stdin:4:1: error: unexpected task response result url' == 1
    : 1
    session:
    result-url: https://cppget.org/?build-result
    EOI
  }

  : agent-checksum
  :
  {
    : empty
    :
    $* <<EOI 2>'stdin:2:16: error: empty task response agent checksum' == 1
    : 1
    agent-checksum:
    EOI

    : redundant
    :
    $* <<EOI 2>'stdin:4:1: error: unexpected task response agent checksum' == 1
    : 1
    session:
    agent-checksum: 1
    EOI
  }

  : task-unexpected
  :
  $* <<EOI 2>'stdin:3:1: error: single task response manifest expected' == 1
  : 1
  session:
  :
  EOI
}

: unknown-name
:
$* <<EOI 2>"stdin:2:1: error: unknown name 'x' in task response manifest" == 1
: 1
x:
EOI

: missed
:
{
  : session
  :
  $* <<EOI 2>'stdin:2:1: error: no task response session specified' == 1
  : 1
  EOI

  : result-url
  :
  $* <<EOI 2>'stdin:4:1: error: no task response result url specified' == 1
  : 1
  session: abc
  challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
  EOI

  : task
  :
  $* <<EOI 2>'stdin:5:1: error: task manifest expected' == 1
  : 1
  session: abcd
  challenge: cc6585375ef81898cc60791b11852e3d2ed9ebb82ebb0874010fe0e6f9ebdb73
  result-url: https://cppget.org/?build-result
  EOI
}