# file      : tests/manifest/result-request.testscript
# license   : MIT; see accompanying LICENSE file

test.options += -rq

: valid
:
: Roundtrip the result request manifest.
:
{
  : all-values
  :
  $* <<EOF >>EOF
  : 1
  session: abcd
  challenge: YQo=
  agent-checksum: 1
  :
  name: libfoo
  version: 1.0
  status: error
  worker-checksum: 1
  EOF

  : no-challenge
  :
  $* <<EOF >>EOF
  : 1
  session: abcd
  agent-checksum: 1
  :
  name: libfoo
  version: 1.0
  status: error
  worker-checksum: 1
  EOF

}

: redefinition
:
{
  : session
  :
  $* <<EOI 2>'stdin:3:1: error: result request session redefinition' == 1
  : 1
  session: abcd
  session: abcd
  EOI

  : challenge
  :
  $* <<EOI 2>'stdin:3:1: error: result request challenge redefinition' == 1
  : 1
  challenge: YQo=
  challenge: YQo=
  EOI

  : agent-checksum
  :
  $* <<EOI 2>'stdin:3:1: error: result request agent checksum redefinition' == 1
  : 1
  agent-checksum: 1
  agent-checksum: 1
  EOI
}

: invalid
:
{
  : empty-session
  :
  $* <<EOI 2>'stdin:2:9: error: empty result request session' == 1
  : 1
  session:
  EOI

  : challenge
  :
  $* <<EOI 2>'stdin:2:12: error: invalid result request challenge' == 1
  : 1
  challenge: abc
  EOI

  : empty-challenge
  :
  $* <<EOI 2>'stdin:2:11: error: empty result request challenge' == 1
  : 1
  challenge:
  EOI

  : empty-agent-checksum
  :
  $* <<EOI 2>'stdin:2:16: error: empty result request agent checksum' == 1
  : 1
  agent-checksum:
  EOI
}

: unknown-name
:
$* <<EOI 2>"stdin:2:1: error: unknown name 'x' in result request manifest" == 1
: 1
x:
EOI

: missed
:
{
  : session
  :
  $* <<EOI 2>'stdin:3:1: error: no result request session specified' == 1
  : 1
  challenge: YQo=
  EOI


  : agent-checksum
  :
  $* <<EOI 2>'stdin:4:1: error: no result request agent checksum specified' == 1
  : 1
  session: abc
  challenge: YQo=
  EOI

  : result
  :
  $* <<EOI 2>'stdin:5:1: error: result manifest expected' == 1
  : 1
  session: abc
  challenge: YQo=
  agent-checksum: 1
  EOI
}