unit-tests/test/script/parser/include.test


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

# file      : unit-tests/test/script/parser/include.test
# copyright : Copyright (c) 2014-2018 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

: none
:
$* <<EOI
.include
.include --once
EOI

: empty
:
touch foo.test;
$* <<EOI
.include foo.test
.include --once foo.test
EOI

: one
:
cat <"cmd" >=foo.test;
$* <<EOI >>EOO
.include foo.test
EOI
cmd
EOO

: multiple
:
cat <"cmd foo" >=foo.test;
cat <"cmd bar" >=bar.test;
$* <<EOI >>EOO
.include foo.test bar.test
EOI
cmd foo
cmd bar
EOO

: once
:
cat <"cmd" >=foo.test;
$* <<EOI >>EOO
.include foo.test
x
.include --once foo.test
.include --once bar/../foo.test
y
.include ../once/foo.test
EOI
cmd
x
y
cmd
EOO

: group-id
:
cat <<EOI >=foo.test;
{
  x = b
}
EOI
$* -s -i <<EOI >>EOO
x = a
.include foo.test
EOI
{
  { # 2-foo-1
  }
}
EOO

: test-id
:
cat <<EOI >=foo.test;
cmd
EOI
$* -s -i <<EOI >>EOO
x = a
.include foo.test
EOI
{
  { # 2-foo-1
    cmd
  }
}
EOO

: invalid-path
:
$* <<EOI 2>>EOE != 0
.include ""
EOI
testscript:1:2: error: invalid testscript include path ''
EOE

: unable-open
:
$* <<EOI 2>>~/EOE/ != 0
.include foo.test
EOI
/testscript:1:2: error: unable to read testscript foo.test: .+/
EOE