tests/test/script/runner/output.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86

# file      : tests/test/script/runner/output.testscript
# license   : MIT; see accompanying LICENSE file

# Some of the tests below (*/script-wd, before/*) are probably more appropriate
# for tests/test/script/script-integration/testscript. Nevertheless let's not
# spread the feature tests among several places.
#

.include ../common.testscript

: after
:
{
  : keep
  :
  {
    : cleanup
    :
    $c <'touch a' && $b config.test.output=keep;
    test -f test/1/a

    : teardown
    :
    $c <<EOI && $b config.test.output=keep;
      +touch a &!a
      -rm a
      EOI
    test -f test/a

    : script-wd
    :
    : There is no working directory created for a empty script, so add a dummy
    : assignment here.
    :
    $c <'a=b' && $b config.test.output=keep;
    test -d test
  }

  : clean
  :
  {
    : cleanup
    :
    $c <'touch a' && $b config.test.output=clean;
    test -f test/1/a == 1

    : teardown
    :
    $c <<EOI && $b config.test.output=clean;
      +touch a &!a
      -rm a
      EOI
    test -f test/a == 1

    : script-wd
    :
    : There is no working directory created for a empty script, so add a dummy
    : assignment here.
    :
    $c <'a=b' && $b config.test.output=clean;
    test -d test == 1
  }
}

: before
:
{
  : fail
  :
  mkdir test &!test/;
  $c <'true' && $b config.test.output=fail@clean 2>>/EOE != 0
    error: working directory test/ exists at the beginning of the test
    EOE

  : warn
  :
  mkdir test &!test/;
  $c <'true' && $b config.test.output=warn@clean 2>>/EOE
    warning: working directory test/ exists at the beginning of the test
    EOE

  : clean
  :
  mkdir test &!test/;
  $c <'true' && $b config.test.output=clean@clean
}