tests/test/script/builtin/touch.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94

# file      : tests/test/script/builtin/touch.testscript
# copyright : Copyright (c) 2014-2019 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

.include ../common.testscript

: file
:
$c <'touch a' && $b

: file-create
:
: Test that file is created. If it didn't then 'rm' would fail.
:
$c <<EOI && $b
touch a &!a;
rm a
EOI

: file-update
:
: Test that existing file touch doesn't fail.
:
$c <<EOI && $b
cat <'' >=a;
touch a
EOI

: no-cleanup
:
: Test that touching an existing file does not register cleanup. If it does
: then the file would be removed while leaving the embedded scope, and so the
: cleanup registered by the first touch would fail.
:
$c <<EOI && $b
{
  +touch a
  {
    touch ../a
  }
}
EOI

: unknown-option
:
$c <<EOI && $b
touch -u 2>"touch: unknown option '-u'" == 1
EOI

: no-args
:
: Test passing no arguments.
:
$c <'touch --no-cleanup 2>"touch: missing file" != 0' && $b

: empty-path
:
: Test touching an empty path.
:
$c <<EOI && $b
touch '' 2>"touch: invalid path ''" != 0
EOI

: dir-update
:
: Test touching an existing directory.
:
$c <<EOI && $b
mkdir a;
touch a 2>~'%touch: cannot create/update .+: .+%' != 0
EOI

: after
:
{
  : success
  :
  $c <<EOI && $b
  touch a;
  touch --after a b
  EOI

  : no-value
  :
  $c <<EOI && $b
  touch --after 2>"touch: missing value for option '--after'" != 0
  EOI

  : not-exists
  :
  $c <<EOI && $b
  touch --after a b 2>~"%touch: cannot obtain file '.+a' modification time: .+%" != 0
  EOI
}