libbuild2/test/script/parser+here-document.test.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213

# file      : libbuild2/test/script/parser+here-document.test.testscript
# copyright : Copyright (c) 2014-2019 Code Synthesis Ltd
# license   : MIT; see accompanying LICENSE file

: end-marker
:
{
  : missing-newline
  :
  $* <'cmd <<' 2>>EOE != 0
  testscript:1:7: error: expected here-document end marker
  EOE

  : missing-exit
  :
  $* <'cmd << != 0' 2>>EOE != 0
  testscript:1:8: error: expected here-document end marker
  EOE

  : missing-empty
  :
  $* <'cmd <<""' 2>>EOE != 0
  testscript:1:7: error: expected here-document end marker
  EOE

  : unseparated-expansion
  :
  $* <'cmd <<FOO$foo' 2>>EOE != 0
  testscript:1:10: error: here-document end marker must be literal
  EOE

  : quoted-single-partial
  :
  $* <"cmd <<F'O'O" 2>>EOE != 0
  testscript:1:7: error: partially-quoted here-document end marker
  EOE

  : quoted-double-partial
  :
  $* <'cmd <<"FO"O' 2>>EOE != 0
  testscript:1:7: error: partially-quoted here-document end marker
  EOE

  : quoted-mixed
  :
  $* <"cmd <<\"FO\"'O'" 2>>EOE != 0
  testscript:1:7: error: partially-quoted here-document end marker
  EOE

  : unseparated
  :
  $* <<EOI >>EOO
  cmd <<EOF!=0
  foo
  EOF
  EOI
  cmd <<EOF != 0
  foo
  EOF
  EOO

  : quoted-single
  :
  $* <<EOI >>EOO
  cmd <<'EOF'
  foo
  EOF
  EOI
  cmd <<EOF
  foo
  EOF
  EOO

  : quoted-double
  :
  $* <<EOI >>EOO
  cmd <<"EOF"
  foo
  EOF
  EOI
  cmd <<EOF
  foo
  EOF
  EOO
}

: indent
:
{
  : basic
  :
  $* <<EOI >>EOO
  cmd <<EOF
    foo
     bar
         baz
    EOF
  EOI
  cmd <<EOF
  foo
   bar
       baz
  EOF
  EOO

  : blank
  :
  $* <<EOI >>EOO
  cmd <<EOF
    foo


    bar
    EOF
  EOI
  cmd <<EOF
  foo


  bar
  EOF
  EOO

  : non-ws-prefix
  :
  $* <<EOI >>EOO
  cmd <<EOF
   x EOF
  EOF
  EOI
  cmd <<EOF
   x EOF
  EOF
  EOO

  : whole-token
  : Test the case where the indentation is a whole token
  :
  $* <<EOI >>EOO
  x = foo bar
  cmd <<"EOF"
    $x
    EOF
  EOI
  cmd <<EOF
  foo bar
  EOF
  EOO

  : long-line
  : Test the case where the line contains multiple tokens
  :
  $* <<EOI >>EOO
  x = foo
  cmd <<"EOF"
     $x bar $x
    EOF
  EOI
  cmd <<EOF
   foo bar foo
  EOF
  EOO

  : unindented
  :
  $* <<EOI 2>>EOE != 0
  cmd <<EOF
   bar
    EOF
  EOI
  testscript:2:1: error: unindented here-document line
  EOE
}

: blank
:
$* <<EOI >>EOO
cmd <<EOF

foo

bar

EOF
EOI
cmd <<EOF

foo

bar

EOF
EOO

: quote
:
: Note: they are still recognized in eval contexts.
:
$* <<EOI >>EOO
cmd <<"EOF"
'single'
"double"
b'o't"h"
('single' "double")
EOF
EOI
cmd <<EOF
'single'
"double"
b'o't"h"
single double
EOF
EOO