tests/submit/submit-dir.testscript


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

# file      : tests/submit/submit-dir.testscript
# license   : MIT; see accompanying LICENSE file

.include data.testscript

: args
{
  : none
  :
  $* 2>>~%EOE% != 0
  %\[.+\] \[brep:error\] \[ref \] \[brep-submit-dir\]: usage: .+brep-submit-dir <dir>%
  EOE

  : dir-not-exist
  :
  $* $~/dir 2>>~%EOE% != 0
    %\[.+\] \[brep:error\] \[ref dir\] \[brep-submit-dir\]: '.+dir' does not exist or is not a directory%
    EOE

  : slash-stripped
  :
  : Test that the trailing slash is stripped from the data directory path.
  :
  $* $~/dir/ 2>>~%EOE% != 0
    %\[.+\] \[brep:error\] \[ref dir\] \[brep-submit-dir\]: '.+dir' does not exist or is not a directory%
    EOE
}

: success
:
{
  test.arguments += $data_dir

  : simulate
  :
  {
    $clone_root_data;

    echo 'simulate: success' >+$data_dir/request.manifest;

    $* >>"EOO";
      : 1
      status: 200
      message: package submission is queued: libhello/0.1.0
      reference: $checksum
      EOO

    test -d $data_dir != 0
  }

  : for-real
  :
  {
    $clone_root_data_clean;

    $* >>"EOO"
      : 1
      status: 200
      message: package submission is queued: libhello/0.1.0
      reference: $checksum
      EOO
  }
}

: failure
:
{
  test.arguments += $data_dir

  : bad-archive
  :
  {
    $clone_root_data_clean;

    echo 'junk' >=$data_dir/libhello-0.1.0.tar.gz;

    $* >>"EOO"
      : 1
      status: 400
      message:\\
      package archive is not valid

      gzip: libhello-0.1.0.tar.gz: not in gzip format
      tar: This does not look like a tar archive
      tar: libhello-0.1.0/manifest: Not found in archive
      tar: Exiting with failure status due to previous errors
        info: libhello-0.1.0.tar.gz does not appear to be a bpkg package
        info: run bpkg pkg-verify for details
      \\
      reference: $checksum
      EOO
  }

  : bad-simulate
  :
  {
    $clone_root_data_clean;

    echo 'simulate: fly' >+$data_dir/request.manifest;

    $* >>"EOO"
      : 1
      status: 400
      message: unrecognized simulation outcome 'fly'
      reference: $checksum
      EOO
  }
}